#!/usr/bin/awk -f
#
# Generates a login.conf file from login.conf.in and an optional
# file containing overrides.
#
# Usage: mklogin.conf [overrides_file] < login.conf.in > login.conf.out
#
# $OpenBSD: mklogin.conf,v 1.4 2009/03/24 20:34:51 sturm Exp $

BEGIN {
	# Default substitutions
	values["DEF_DATASIZE_MAX"]="512M"
	values["DEF_DATASIZE_CUR"]="512M"
	values["DEF_MAXPROC_MAX"]="256"
	values["DEF_MAXPROC_CUR"]="128"
	values["DEF_OPENFILES_CUR"]="128"
	values["STAFF_DATASIZE_MAX"]="infinity"
	values["STAFF_DATASIZE_CUR"]="512M"
	values["STAFF_MAXPROC_MAX"]="512"
	values["STAFF_MAXPROC_CUR"]="128"
	values["STAFF_OPENFILES_CUR"]="128"

	# Optional overrides
	if (ARGC > 1) {
		while (getline override < ARGV[1]) {
			split(override, ov)
			values[ov[0] ""]=ov[1] ""
		}
		ARGC--
	}
}

# Read in login.conf template, do substitutions and output the result
{
	for (key in values)
		gsub("@" key "@", values[key], $0)
	print $0
}
